move IT Home Base

E-Mail

anonymous@undisclosed.example.com (Anonymous) — Fri, 29 Nov 2019 10:58:39 +0000

E-Mail

Damit dieses Script funktionieren kann muss zuvor die E-Mail Funktion in der Konfigurationsdatei opensim.ini eingeschaltet und konfiguriert werden.

string email_address = "adresse@domain.xyz"; // who will receive the messages
string hname = "User Name"; // name that will be displayed in hover text as receiver of mail
string date;
string name;
string sim;
default
{
    state_entry() {

        //Send an email to a normal email account
        llSetText("click to send " + hname + " an email",<1,1,1>,1);
        llEmail( email_address, "Initializing Email Module", "[STARTUP COMPLETE]");
    }

    touch_start( integer num_detected ) {
        integer i = 0;
        date = llGetDate();
        name = llDetectedName(i);
        sim = llGetRegionName();

        // Send another email, telling who touched the prim.
        do
            llEmail( email_address, "Prim Touched", "I was touched by: " + llDetectedName(i) + "\nKey: " + (string) llDetectedKey(i) + "\n On the Following Date: " + date);
        while(++i < num_detected);
        llSay(0,"------------------------>");
        llSay(0,"E-Mail sent from " + name + "@" + sim + ".DOMAIN");
        llSay(0,"------------------------>");
        llPlaySound("Boing", 1.0);
    }
}

Sim Crash Logger

anonymous@undisclosed.example.com (Anonymous) — Fri, 29 Nov 2019 10:58:43 +0000

Sim Crash Logger

//********************************************************
//This Script was pulled out for you by YadNi Monde from the SL FORUMS at http://forums.secondlife.com/forumdisplay.php?f=15, it is intended to stay FREE by it s author(s) and all the comments here in ORANGE must NOT be deleted. They include notes on how to use it and no help will be provided either by YadNi Monde or it s Author(s). IF YOU DO NOT AGREE WITH THIS JUST DONT USE!!!
//********************************************************

/////////////////////////////////////////
//SIM CRASH/REBOOT LOGGER
//by: Kyrah Abattoir
/////////////////////////////////////////

integer timering = 10;//the polling rate, put the speed you wish, in seconds

//there we go...
integer UNIX;
string _buffer;
list log;
integer span = 0;
float fps;
float dilation;
integer crash = 0;
string date;
//2004-08-27T00:56:21.785886Z

default
{
    state_entry()
    {
        llSetTimerEvent(timering);//starting our timer
    }
    timer()
    {
        string timestamp = llGetTimestamp();
        list temp = llParseString2List(timestamp,["T",":",":","."],[]);
        integer _hour = llList2Integer(temp,1) + 4;
        if(_hour > 24) //getting the hours
            _hour = _hour - 24 ;

        string _date = llList2String(temp,0);
        integer _min = llList2Integer(temp,2);
        integer _sec = llList2Integer(temp,3);
        string buffer;

        if(date == _date) //daily reset of the average fps and dilation
            span++;
        else
        {
            span = 1;
            date = _date;
            fps = 0;
            dilation = 0;
        }

        fps += llGetRegionFPS();
        dilation += llGetRegionTimeDilation();
        integer avg_FPS = (integer)(fps/span);
        string avg_dilation= llGetSubString((string)(dilation/span),0,3);

        buffer += llGetRegionName();
        buffer += "\n FPS:"+(string)avg_FPS;
        buffer += " dil. :"+(string)avg_dilation;
        //buffer += "\n" + llDumpList2String(log,"\n");

        integer _UNIX = _sec + _min * 60 + _hour * 3600;//making our timestamp
       
        if (_UNIX - UNIX > timering + 5 && UNIX != 0)//okay the delay has been waaay too olong, it probably crashed or rebooted
        {
            crash++;
            log += (string)_date + " - " + (string)_hour+ ":"+(string)_min+":"+(string)_sec;
            if(llGetListLength(log) > 9)
                log = llDeleteSubList(log,0,0);
        }
        buffer += "\n sim crashes: " + (string)crash + "\n last crash: \n" + llDumpList2String(log,"\n");
        if(_buffer != buffer); //display
        {
            llSetText(buffer,<1,1,1>,1.0);
            _buffer = buffer;   
        }
        UNIX = _UNIX;
    }
}

Sim Statistik

anonymous@undisclosed.example.com (Anonymous) — Fri, 29 Nov 2019 10:58:43 +0000

Sim Statistik

Zeigt durch klicken auf ein Prim aktuelle Sim-Statistikwerte an.

//sim stats
 
default
{
    state_entry()
    {
        llSleep(0.5);
    }
    touch_start(integer num_detected)
    {
        llSetText("Region: " + (string)llGetRegionName()
                             + "\n Dilation: "
                             + (string)llGetRegionTimeDilation()
                             + "\n Host: " + (string)llGetSimulatorHostname(),<1,1,1>,1);
    }
}

Teleport to Sim

anonymous@undisclosed.example.com (Anonymous) — Fri, 29 Nov 2019 10:58:44 +0000

Teleport to Sim

string teleport_message = "Sie teleportieren nun zur Sim M34";
string destination_name = "Sim M34 von OpenSIM";
vector destination_landing_point = <170,156,23>;
vector landing_point_facing = <150,120,34>;
default
{
    state_entry()
    {
        llSay(0, "Script running");
        llSetText("Teleport zu\n" + destination_name, <1,1,1>, 1);
        llSetTextureAnim(ANIM_ON | SMOOTH | ROTATE | LOOP, ALL_SIDES, 0, 0, 1.0, 1000, 0.07);
    }
    
    touch_start(integer number)
    {   llRegionSay(-1, "occulus," + llDetectedKey(0) + "," + destination_name);
        llMapDestination("DOMAIN:9090", destination_landing_point, landing_point_facing);
        
    }
    

}

Häuser / Gebäude / Möbel / Einrichtungsgegenstände

anonymous@undisclosed.example.com (Anonymous) — Fri, 29 Nov 2019 10:58:46 +0000

Häuser / Gebäude / Möbel / Einrichtungsgegenstände

Nur für Sim-Owner !

Sammlung

http://opensimulator.org/wiki/Free_Assets#Buildings

Terrains

anonymous@undisclosed.example.com (Anonymous) — Fri, 29 Nov 2019 10:58:46 +0000

Terrains

Die Downloads auf dieser Seite enthalten sowohl reine Terrains, also nur Bodenstrukturen (Land, Wasser, Berge), als auch komplette Regionen mitsamt auf den Terrains enthaltene Gebäude. Die angebotenen Downloads sind zu Demonstrationszwecken gedacht und lassen sich nach dem Importieren auf der eigenen Sim individuell nach den eigenen Vorstellungen verändern und erweitern.

Regionen

Komplette Regionen mitsamt allen Inhalten lassen sich von OpenSIM-Betreibern über die Serverkonsole von OpenSIM importieren. Dabei werden alle Terrainstrukturen und alle Prims auf der Region durch die importierten Region ersetzt. Zunächst muß die gedownloadete Datei *.oar in das OpenSIM Verzeichnis kopiert werden. Dann wählt man über die Serverkonsole von OpenSIM mit dem Kommando

change region regionname

aus auf welcher Region die importierte Region eingesetzt werden soll (falls man mehr als 1 Region hat).

Die Serverkonsole zeigt den Namen der aktuell ausgewählten Region stets an (Root ist die ersterstellte Region). Dann importiert man die neue Region mit dem Kommando

load oar dateiname.oar

Es wird nun der Inhalt der Region komplett gegen den Inhalt der importierten Region ersetzt. Die Serverkonsole zeigt eine Reihe schnell ablaufender Vorgänge, je nachdem wieviel Inhalte die importierte Region hat. Dies kann einen Moment dauern. Nachdem OpenSIM mit dem Import fertig ist wird die neue Region angezeigt und kann sofort genutzt werden.

Flache 1x1 Region mit einem Wohn- und einem Bürogebäude

Eine sehr flache, gut bebaubare Region die jeweils ein Wohnhaus und ein Bürogebäude enthält. Das Wohnhaus ist rustikal aufgebaut, enthält einen Kamin mit flackerndem Feuer, öffnungsbare Doppelflügeltüren und eine Dachkammer. Das moderne Bürogebäude kann auch als Wohnhaus benutzt werden, enthält eine große Dachterrasse, ausladend breite Treppen und einen integrierten Pool.

Leider enthalten die beiden Freebie-Häuser einen kleinen Schönheitsfehler: man kann ohne Anpassung nicht durch die Türen gehen, denn der Ersteller der Häuser hat den Türrahmen „hollow“ gemacht und bisher ist es in OpenSIM noch nicht möglich durch ein Loch eines Prims hindurchzugehen. Man muss entweder die Türrrahmen gegen einzelne Balken austauschen (korrekte Lösung), oder den Türrahmen auf „Phantom“ setzen (Notlösung die aber schneller geht).

Download

Terrains

Komplette Terrains (Bodenstrukturen mit Wasser, Land und Berge) lassen sich von OpenSIM-Betreibern über die Serverkonsole von OpenSIM importieren. Dabei werden alle Terrainstrukturen auf der Region durch das importierte Terrain ersetzt. Zunächst muß die gedownloadete Terrain-Datei (*.f32 oder *.raw) in das OpenSIM Verzeichnis kopiert werden. Dann wählt man über die Serverkonsole von OpenSIM mit dem Kommando

change region regionname

aus auf welcher Region das importierte Terrain eingesetzt werden soll (falls man mehr als 1 Region hat).

Die Serverkonsole zeigt den Namen der aktuell ausgewählten Region stets an (Root ist die ersterstellte Region). Dann importiert man das neue Terrain mit dem Kommando

terrain load dateiname.raw

Es wird nun das Terrain der Region komplett gegen das neue Terrain der ausgewählten Region ersetzt. Die Serverkonsole zeigt eine Reihe schnell ablaufender Vorgänge, je nachdem wieviel verschiedene Strukturen das importierte Terrain hat. Dies geht normalerweise sehr schnell. Nachdem OpenSIM mit dem Import fertig ist wird das neue Terrain angezeigt und kann sofort genutzt werden.

1x1 Terrains

Ein einfaches, superflaches Terrain ohne Wasser das gut zu bebauen ist und sich als Ausgangsbasis eignet wenn man einfach nur eine möglichst große Fläche haben möchte. Die Größe ist bewusst so gewählt damit man dieses Terrain aneinander kacheln kann. Nebeneinanderliegende Terrains ergeben somit eine grösser werdende, zusammenhängende Fläche ohne Lücken (übergangslos).

Download

Fire Particle

anonymous@undisclosed.example.com (Anonymous) — Fri, 29 Nov 2019 10:58:40 +0000

Fire Particle

//// "Fire" PARTICLE TEMPLATE v1 - by Jopsy Pendragon - 4/8/2008
//// You are free to use this script as you please, so long as you include this line:
//** The original 'free' version of this script came from THE PARTICLE LABORATORY. **//

// SETUP:  Drop one optional particle texture and this script into a prim.
// Particles should start automatically. (Reset) the script if you insert a
// particle texture later on.  Add one or more CONTROLLER TEMPLATES to any
// prims in the linked object to control when particles turn ON and OFF.

// Customize the particle_parameter values below to create your unique 
// particle effect and click SAVE.  Values are explained along with their
// min/max and default values further down in this script.


string  CONTROLLER_ID = "A"; // See comments at end regarding CONTROLLERS.
integer AUTO_START = TRUE;   // Optionally FALSE only if using CONTROLLERS.

list particle_parameters=[]; // stores your custom particle effect, defined below.
list target_parameters=[]; // remembers targets found using TARGET TEMPLATE scripts.

default {
    state_entry() {
        particle_parameters = [  // start of particle settings
           // Texture Parameters:
           PSYS_SRC_TEXTURE, llGetInventoryName(INVENTORY_TEXTURE, 0), 
           PSYS_PART_START_SCALE, <.4,.4,FALSE>,  PSYS_PART_END_SCALE, <.5,.5, FALSE>, 
           PSYS_PART_START_COLOR, <1,1,1>,    PSYS_PART_END_COLOR, <.4,.1,0>, 
           PSYS_PART_START_ALPHA, (float).8,            PSYS_PART_END_ALPHA, (float).0,     
         
           // Production Parameters:
           PSYS_SRC_BURST_PART_COUNT, (integer)1, 
           PSYS_SRC_BURST_RATE, (float) 0.0,  
           PSYS_PART_MAX_AGE, (float)1.5, 
           PSYS_SRC_MAX_AGE,(float) 0.0,  
        
           // Placement Parameters:
           PSYS_SRC_PATTERN, (integer)2, // 1=DROP, 2=EXPLODE, 4=ANGLE, 8=ANGLE_CONE,
           
           // Placement Parameters (for any non-DROP pattern):
           PSYS_SRC_BURST_SPEED_MIN, (float).1,   PSYS_SRC_BURST_SPEED_MAX, (float).3, 
        // PSYS_SRC_BURST_RADIUS, 0.0,
        
           // Placement Parameters (only for ANGLE & CONE patterns):
           PSYS_SRC_ANGLE_BEGIN, (float) .03*PI,     PSYS_SRC_ANGLE_END, (float)0.00*PI,  
        // PSYS_SRC_OMEGA, <0,0,0>, 
        
           // After-Effect & Influence Parameters:
           PSYS_SRC_ACCEL, <0.0,0.0,1.5>,  
        // PSYS_SRC_TARGET_KEY,      llGetLinkKey(llGetLinkNum() + 1),       
              
           PSYS_PART_FLAGS, (integer)( 0         // Texture Options:     
                                | PSYS_PART_INTERP_COLOR_MASK   
                                | PSYS_PART_INTERP_SCALE_MASK   
                                | PSYS_PART_EMISSIVE_MASK   
                                | PSYS_PART_FOLLOW_VELOCITY_MASK
                                                  // After-effect & Influence Options:
                                | PSYS_PART_WIND_MASK            
                                | PSYS_PART_BOUNCE_MASK          
                             // | PSYS_PART_FOLLOW_SRC_MASK     
                             // | PSYS_PART_TARGET_POS_MASK     
                             // | PSYS_PART_TARGET_LINEAR_MASK   
                            ) 
            //end of particle settings                     
        ];
        
        if ( AUTO_START ) llParticleSystem( particle_parameters );
        
    }
    
    link_message( integer sibling, integer num, string mesg, key target_key ) {
        if ( mesg != CONTROLLER_ID ) { // this message isn't for me.  Bail out.
            return;
        } else if ( num == 0 ) { // Message says to turn particles OFF:
            llParticleSystem( [ ] );
        } else if ( num == 1 ) { // Message says to turn particles ON:
            llParticleSystem( particle_parameters + target_parameters );
        } else if ( num == 2 ) { // Turn on, and remember and use the key sent us as a target:
            target_parameters = [ PSYS_SRC_TARGET_KEY, target_key ];
            llParticleSystem( particle_parameters + target_parameters );
        } else { // bad instruction number
            // do nothing.
        }            
    }
        
}


//============================= About Parameters =============================
// There are 22-ish NAMED attributes that affect a particle display.
// To customize a display you give each a VALUE.
// For example: PSYS_PART_START_COLOR is a named attribute,
// and <1.0, 0.5, 0.0> is a color VALUE (orange, in this case).
// 
// As long as your 'names' and 'values' are paired up properly, they can
// be in any order!  Any you omit a pair, it reverts to a default value.

//============================= Texture Parameters =============================
//
// TEXTURE, can be an "Asset UUID" key copied from a texture 
//          that you have full permissions to, or the name of
//          a texture in the prim's inventory.
//
// SCALE, (size) 0.0 to 4.0 meters wide, by 0.0 to 4.0 meters tall. (default 1x1)
//          Textures are FLAT, so the 'z' part of the vector is ignored.
//          Values smaller than 0.04x0.04 may not get rendered at all.
//          Tiny particles vanish if the viewer is not near them.
//
// BEGIN_SCALE sets particle start size.  
// END_SCALE (end size) is ignored, if the INTERP_SCALE_MASK option is disabled.
//
// COLOR, < RED, GREEN, BLUE > from <0.00,0.00,0.00> (black) to <1.00,1.00,1.00> (white/default)
// ALPHA, 1.0 = 100% visible(default), 0.0 = invisible.  Less than 0.1 might not get seen.
// START_COLOR and START_ALPHA set the color and transparency of newly created particles. 
// END_COLOR and END_ALPHA are ignored, if the INTERP_COLOR_MASK option is disabled.
         
         
//============================= Production Parameters =============================
//
// BURST_PART_COUNT: quantity of particles per burst, 1 to 4096 (default 1), 
//
// BURST_RATE: seconds to delay between particle bursts. 0.0 to 30.0 (default 0.1)
//
// PART_MAX_AGE: particle lifespan in seconds, 0.00 to 30.0 (default=10.0)
//               PART_MAX_AGE less than 0.5 might not be visible.
//
// The default total number of particles that can be seen is 4096, if one or more 
// emitters try to create more than that, many will not be seen, and it may cause
// viewer lag.  Use as few particles as you can for your effect:
// AGE/RATE * COUNT will tell you approximately how many particles your emitter creates.
//
// SRC_MAX_AGE: emitter auto shut-off timer. 1.0 to 60.0 seconds. 0.0 = never stop. (default)


//============================= Placement Parameters =============================
//                
// PATTERN:   
//      DROP, ignores all other placement settings.
//      EXPLODE, spray particles in all directions
//      ANGLE, sprays a flat "fan" shape defined by ANGLE_BEGIN and END values
//      CONE, sprays "ring" or "cone" shapes defined by ANGLE_BEGIN and END values
//
// RADIUS:  0.0 to 50.0?  distance from emitter to create new particles
//      (RADIUS is disabled with DROP pattern and the FOLLOW_SRC & TARGET_LINEAR options)
//        
// SPEED: 0.00 to 50.0?  Sets min/max starting velocities for non-drop patterns. (default: 1.0)
//        
// ANGLE_BEGIN & END:  0.00*PI (up) to 1.00*PI (down),  (Only for ANGLE & CONE patterns)
//       (Values work much like the Sphere-prim's DIMPLE attributes.) (defaults: 0.0)
//
// OMEGA: <x,y,z> Sets how much to rotate angle/cone spray direction after
//                every burst. 0.0 to PI?  (default: <0,0,0>)

//======================== After-Effects & Influence Parameters ================
//
// ACCEL, x,y,z 0.0 to 50.0?  sets a constant force, (affects all patterns)
//          Causes particles to drift up/down or in a compass direction.
//          Use ACCEL to create the illusion of (anti-)gravity or a directional wind.
//          (ineffective with TARGET_LINEAR option)
//       
// TARGET_KEY,  "key", (requires the TARGET option be enabled).  
//       "key" can be a variety of many different things:
         // llGetOwner()
         // llGetKey() target self 
         // llGetLinkKey(1) target parent prim
         // llGetLinkKey(llGetLinkNum() + 1) target next prim in link set 
         //
         // WARNING: New copies of objects get new keys, you can't simply paste
         // a prim's key into your script and expect it to always work.  Visit
         // the Particle Laboratory's section on TARGETS for a variety of ways
         // to dynamically find your target's key. There are different 'best ways'
         // depending on if your target is linked to your emitter or not.


//============================= About Options =============================
//    
// Each option may be ON/ENABLED (no leading // )
// or OFF/DISABLED (by putting a // in front of it.)
// Options are combined together in a special way, (using the | symbol).
// This creates one single Parameter for PSYS_PART_FLAGS.

              
//============================= Texture Options =============================
//
// EMISSIVE: identical to "full bright" setting on prims     
//   
// FOLLOW_VELOCITY: particle texture 'tilts' towards the direction it's moving
//
// INTERP_COLOR: causes particle COLOR and ALPHA(transparency) to change over it's lifespan
//
// INTERP_SCALE: causes particle SCALE(size) to change over it's lifespan


//======================== After-Effects & Influences Options ================
//
// BOUNCE:  particles bounce up from the z-altitude of emitter, and cannot fall below it.
//
// WIND: the sim's wind will push particles around
//
// FOLLOW_SRC: makes particles move (but not rotate) if their emitter moves, (disables RADIUS)
//
// TARGET_POS: causes particles to arrive at a some target at end of of their lifespan.
//
// TARGET_LINEAR: forces particles to form into an even line from emitter to target
//                and forces a DROP-like pattern and disables effects of WIND and ACCEL



//========================================================================
//======================== USING CONTROL TEMPLATES =======================
//
// Want to control when your particles turn ON and OFF?   You can!
// 
// Drop one (or more) of the CONTROL TEMPLATES from the particle laboratory
// into your object containing this script.  That's it!

// Your controls should be effective immediately.  (Some controllers can be
// adjusted and tuned, open them and read the USAGE notes to see.)
//
// One control template can control several particle templates in the
// same object.   (keep in mind that each prim can only have ONE
// particle effect active at a time).
//
// The 'particle_effect_name' value must be the same in both the control
// and particle template to work.  You can change that value and have
// a controller for one effect, and a different controller for a different
// effect in the same object.
//


//======================================== END ===============================default